ActionScript 3.0 Language and Components Reference | All Packages | All Classes | Language Elements | Index | Appendixes | Conventions | Frames No Frames |
BlurFilter

Package | flash.filters
Class | public final class BlurFilter
Inheritance | BlurFilter BitmapFilter Object

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The BlurFilter class lets you apply a blur visual effect to display objects. A blur effect softens the details of an image. You can produce blurs that range from a softly unfocused look to a Gaussian blur, a hazy appearance like viewing an image through semi-opaque glass. When the `quality` property of this filter is set to low, the result is a softly unfocused look. When the `quality` property is set to high, it approximates a Gaussian blur filter. You can apply the filter to any display object (that is, objects that inherit from the DisplayObject class), such as MovieClip, SimpleButton, TextField, and Video objects, as well as to BitmapData objects.

To create a new filter, use the constructor `new BlurFilter()`. The use of filters depends on the object to which you apply the filter:

- To apply filters to movie clips, text fields, buttons, and video, use the `filters` property (inherited from DisplayObject). Setting the `filters` property of an object does not modify the object, and you can remove the filter by clearing the `filters` property.
- To apply filters to BitmapData objects, use the `BitmapData.applyFilter()` method. Calling `applyFilter()` on a BitmapData object takes the source BitmapData object and the filter object and generates a filtered image as a result.

If you apply a filter to a display object, the `cacheAsBitmap` property of the display object is set to `true`. If you remove all filters, the original value of `cacheAsBitmap` is restored.

This filter supports Stage scaling. However, it does not support general scaling, rotation, and skewing. If the object itself is scaled (`scaleX` and `scaleY` are not set to 100%), the filter effect is not scaled. It is scaled only when the user zooms in on the Stage.

A filter is not applied if the resulting image exceeds 2880 pixels in width or height. If, for example, you zoom in on a large movie clip with a filter applied, the filter is turned off if the resulting image exceeds the limit of 2880 pixels.

View the examples

See also

flash.display.DisplayObject.filters
flash.display.DisplayObject.cacheAsBitmap
flash.display.BitmapData.applyFilter()

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | blurX : Number The amount of horizontal blur. | BlurFilter
|  | blurY : Number The amount of vertical blur. | BlurFilter
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | prototype : Object [static] A reference to the prototype object of a class or function object. | Object
|  | quality : int The number of times to perform the blur. | BlurFilter

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | BlurFilter(blurX:Number = 4.0, blurY:Number = 4.0, quality:int = 1) Initializes the filter with the specified parameters. | BlurFilter
|  | clone():BitmapFilter Returns a copy of this filter object. | BlurFilter
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Property Detail

blurX | property

`blurX:Number` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The amount of horizontal blur. Valid values are from 0 to 255 (floating point). The default value is 4. Values that are a power of 2 (such as 2, 4, 8, 16 and 32) are optimized to render more quickly than other values.

Implementation
`public function get blurX():Number`
`public function set blurX(value:Number):void`

blurY | property |

`blurY:Number` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The amount of vertical blur. Valid values are from 0 to 255 (floating point). The default value is 4. Values that are a power of 2 (such as 2, 4, 8, 16 and 32) are optimized to render more quickly than other values.

Implementation
`public function get blurY():Number`
`public function set blurY(value:Number):void`

quality | property |

`quality:int` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The number of times to perform the blur. The default value is `BitmapFilterQuality.LOW`, which is equivalent to applying the filter once. The value `BitmapFilterQuality.MEDIUM` applies the filter twice; the value `BitmapFilterQuality.HIGH` applies it three times and approximates a Gaussian blur. Filters with lower values are rendered more quickly.

For most applications, a `quality` value of low, medium, or high is sufficient. Although you can use additional numeric values up to 15 to increase the number of times the blur is applied, higher values are rendered more slowly. Instead of increasing the value of `quality`, you can often get a similar effect, and with faster rendering, by simply increasing the values of the `blurX` and `blurY` properties.

You can use the following BitmapFilterQuality constants to specify values of the `quality` property:

- `BitmapFilterQuality.LOW`
- `BitmapFilterQuality.MEDIUM`
- `BitmapFilterQuality.HIGH`

Implementation
`public function get quality():int`
`public function set quality(value:int):void`
Constructor Detail

BlurFilter | () | Constructor

`public function BlurFilter(blurX:Number = 4.0, blurY:Number = 4.0, quality:int = 1)`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Initializes the filter with the specified parameters. The default values create a soft, unfocused image.

Parameters

| `blurX:Number` (default = `4.0`)`` — The amount to blur horizontally. Valid values are from 0 to 255.0 (floating-point value).
| `blurY:Number` (default = `4.0`)`` — The amount to blur vertically. Valid values are from 0 to 255.0 (floating-point value).
| `quality:int` (default = `1`)`` — The number of times to apply the filter. You can specify the quality using the BitmapFilterQuality constants: `flash.filters.BitmapFilterQuality.LOW` `flash.filters.BitmapFilterQuality.MEDIUM` `flash.filters.BitmapFilterQuality.HIGH` High quality approximates a Gaussian blur. For most applications, these three values are sufficient. Although you can use additional numeric values up to 15 to achieve different effects, be aware that higher values are rendered more slowly.

Method Detail

clone | () | method

`override public function clone():BitmapFilter`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Returns a copy of this filter object.

Returns

| `BitmapFilter` — A new BlurFilter instance with all the same properties as the original BlurFilter instance.

Examples How to use examples
BlurFilterExample.as
The following example creates a dark yellow square and applies a Gaussian-style blur filter to it. The general workflow for this example is as follows:

1. Import the required classes.
2. Declare three properties used in the `draw()` function, which draws the object to which the blur filter is applied.
3. Create the `BlurFilterExample()` constructor function, which does the following:
   - Calls the `draw()` function, which is declared later.
   - Declares a `filter` variable as a BitmapFilter object and assigns it to the return of a call to `getBitmapFilter()`.
   - Creates a new Array object `myFilters` and adds `filter` to the array, and assigns `myFilters` to the `filters` property of the BlurFilterExample object. This applies all filters found in `myFilters`, which in this case is only `filter`.
4. Create the `getBitmapFilter()` function to create and set properties for the filter.
5. Create the `draw()` function. This function uses methods of the Graphics class, accessed through the `graphics` property of the Sprite class, to draw the square.

    package {
        import flash.display.Sprite;
        import flash.filters.BitmapFilter;
        import flash.filters.BitmapFilterQuality;
        import flash.filters.BlurFilter;

        public class BlurFilterExample extends Sprite {
            private var bgColor:uint = 0xFFCC00;
            private var size:uint    = 80;
            private var offset:uint  = 50;

            public function BlurFilterExample() {
                draw();
                var filter:BitmapFilter = getBitmapFilter();
                var myFilters:Array = new Array();
                myFilters.push(filter);
                filters = myFilters;
            }

            private function getBitmapFilter():BitmapFilter {
                var blurX:Number = 30;
                var blurY:Number = 30;
                return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
            }

            private function draw():void {
                graphics.beginFill(bgColor);
                graphics.drawRect(offset, offset, size, size);
                graphics.endFill();
            }
        }
    }

Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Tue May 20 2008, 04:02 AM -07:00