ActionScript 3.0 Language and Components Reference | All Packages | All Classes | Language Elements | Index | Appendixes | Conventions | Frames No Frames |
SpaceJustifier

Package | flash.text.engine
Class | public final class SpaceJustifier
Inheritance | SpaceJustifier TextJustifier Object

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

The SpaceJustifier class represents properties that control the justification options for text lines in a text block.

Use the constructor `new SpaceJustifier()` to create a SpaceJustifier object before setting its properties. Setting the properties of a SpaceJustifier object after you apply it to a TextBlock does not invalidate the TextBlock.

View the examples

See also

LineJustification
TextBlock.textJustifier
TextJustifier

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | letterSpacing : Boolean Specifies whether to use letter spacing during justification. | SpaceJustifier
|  | lineJustification : String Specifies the line justification for the text in a text block. | TextJustifier
|  | locale : String [read-only] Specifies the locale to determine the justification rules for the text in a text block. | TextJustifier
|  | prototype : Object [static] A reference to the prototype object of a class or function object. | Object

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | SpaceJustifier(locale:String = "en", lineJustification:String = "unjustified", letterSpacing:Boolean = false) Creates a SpaceJustifier object. | SpaceJustifier
|  | getJustifierForLocale(locale:String):TextJustifier [static] Constructs a default TextJustifier subclass appropriate to the specified locale. | TextJustifier
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Property Detail

letterSpacing | property

`letterSpacing:Boolean` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Specifies whether to use letter spacing during justification.

Implementation
`public function get letterSpacing():Boolean`
`public function set letterSpacing(value:Boolean):void`
Constructor Detail

SpaceJustifier | () | Constructor

`public function SpaceJustifier(locale:String = "en", lineJustification:String = "unjustified", letterSpacing:Boolean = false)`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Creates a SpaceJustifier object. The LineJustification class contains constants for specifying the types of line justification that you can apply.

Parameters

| `locale:String` (default = "`en`")`` — The locale to determine the justification rules. The default value is `"en"`.
| `lineJustification:String` (default = "`unjustified`")`` — The type of line justification for the paragraph. Use `LineJustification` constants for this property. The default value is `LineJustification.UNJUSTIFIED`.
| `letterSpacing:Boolean` (default = `false`)`` — Specifies whether to use letter spacing during justification. The default value is `false`.

Throws

| `ArgumentError` — The `locale` specified is `null` or too short to represent a valid locale.
| `ArgumentError` — The `lineJustification` specified is not a member of `LineJustification`.

See also

LineJustification
Examples How to use examples
SpaceJustifierExample.as
The following example uses letter spacing and justifies all of a block of text except for the last line.

    package {
        import flash.display.Sprite;
        import flash.text.engine.TextBlock;
        import flash.text.engine.TextElement;
        import flash.text.engine.TextLine;
        import flash.text.engine.ElementFormat;
        import flash.text.engine.SpaceJustifier;
        import flash.text.engine.LineJustification;

        public class SpaceJustifierExample extends Sprite {

            public function SpaceJustifierExample():void {
                var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " +
                "sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut " +
                "enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut " +
                "aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit " +
                "in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur " +
                "sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt " +
                "mollit anim id est laborum.";

                var format:ElementFormat = new ElementFormat(null, 12, 0xCC0000);
                var textElement:TextElement = new TextElement(str, format);
                var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_BUT_LAST);
                spaceJustifier.letterSpacing = true;
                var textBlock:TextBlock = new TextBlock();
                textBlock.content = textElement;
                textBlock.textJustifier = spaceJustifier;
                createLines(textBlock);
            }

            private function createLines(textBlock:TextBlock):void {

                var yPos = 20;
                var textLine:TextLine = textBlock.createTextLine (null, 150);

                while (textLine)
                {
                    addChild(textLine);
                    textLine.x = 15;
                    yPos += textLine.textHeight+2;
                    textLine.y = yPos;
                    textLine = textBlock.createTextLine(textLine, 150);
                }
            }
        }
    }

Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Tue May 20 2008, 04:02 AM -07:00