ActionScript 3.0 Language and Components Reference | All Packages | All Classes | Language Elements | Index | Appendixes | Conventions | Frames No Frames |
Event

Package | flash.events
Class | public class Event
Inheritance | Event Object
Subclasses | ActivityEvent, ContextMenuEvent, FocusEvent, HTTPStatusEvent, KeyboardEvent, MouseEvent, NetStatusEvent, ProgressEvent, ShaderEvent, StatusEvent, SyncEvent, TextEvent, TimerEvent

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The Event class is used as the base class for the creation of Event objects, which are passed as parameters to event listeners when an event occurs.

The properties of the Event class carry basic information about an event, such as the event's type or whether the event's default behavior can be canceled. For many events, such as the events represented by the Event class constants, this basic information is sufficient. Other events, however, may require more detailed information. Events associated with a mouse click, for example, need to include additional information about the location of the click event and whether any keys were pressed during the click event. You can pass such additional information to event listeners by extending the Event class, which is what the MouseEvent class does. The Flash® Player API defines several Event subclasses for common events that require additional information. Events associated with each of the Event subclasses are described in the documentation for each class.

The methods of the Event class can be used in event listener functions to affect the behavior of the event object. Some events have an associated default behavior. For example, the `doubleClick` event has an associated default behavior that highlights the word under the mouse pointer at the time of the event. Your event listener can cancel this behavior by calling the `preventDefault()` method. You can also make the current event listener the last one to process an event by calling the `stopPropagation()` or `stopImmediatePropagation()` method.

View the examples

See also

flash.events.EventDispatcher
Event objects

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | bubbles : Boolean [read-only] Indicates whether an event is a bubbling event. | Event
|  | cancelable : Boolean [read-only] Indicates whether the behavior associated with the event can be prevented. | Event
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | currentTarget : Object [read-only] The object that is actively processing the Event object with an event listener. | Event
|  | eventPhase : uint [read-only] The current phase in the event flow. | Event
|  | prototype : Object [static] A reference to the prototype object of a class or function object. | Object
|  | target : Object [read-only] The event target. | Event
|  | type : String [read-only] The type of event. | Event

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) Creates an Event object to pass as a parameter to event listeners. | Event
|  | clone():Event Duplicates an instance of an Event subclass. | Event
|  | formatToString(className:String, ... arguments):String A utility function for implementing the toString() method in your custom Event class. | Event
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isDefaultPrevented():Boolean Checks whether preventDefault() has been called on the event. | Event
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | preventDefault():void Cancels an event's default behavior if that behavior can be canceled. | Event
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | stopImmediatePropagation():void Prevents processing of any event listeners in the current node and any subsequent nodes in the event flow. | Event
|  | stopPropagation():void Prevents processing of any event listeners in nodes subsequent to the current node in the event flow. | Event
|  | toString():String Returns a string containing all the properties of the Event object. | Event
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Public Constants

| Constant | Defined By
--- | --- | ---
|  | ACTIVATE : String = "activate" [static] Defines the value of the type property of an activate event object. | Event
|  | ADDED : String = "added" [static] Defines the value of the type property of an added event object. | Event
|  | ADDED_TO_STAGE : String = "addedToStage" [static] Defines the value of the type property of an addedToStage event object. | Event
|  | CANCEL : String = "cancel" [static] Defines the value of the type property of a cancel event object. | Event
|  | CHANGE : String = "change" [static] Defines the value of the type property of a change event object. | Event
|  | CLEAR : String = "clear" [static] Defines the value of the type property of a clear event object. | Event
|  | CLOSE : String = "close" [static] Defines the value of the type property of a close event object. | Event
|  | COMPLETE : String = "complete" [static] Defines the value of the type property of a complete event object. | Event
|  | CONNECT : String = "connect" [static] Defines the value of the type property of a connect event object. | Event
|  | COPY : String = "copy" [static] Defines the value of the type property of a copy event object. | Event
|  | CUT : String = "cut" [static] Defines the value of the type property of a cut event object. | Event
|  | DEACTIVATE : String = "deactivate" [static] Defines the value of the type property of a deactivate event object. | Event
|  | ENTER_FRAME : String = "enterFrame" [static] Defines the value of the type property of an enterFrame event object. | Event
|  | EXIT_FRAME : String = "exitFrame" [static] Defines the value of the type property of an exitFrame event object. | Event
|  | FRAME_CONSTRUCTED : String = "frameConstructed" [static] Defines the value of the type property of an frameConstructed event object. | Event
|  | FULLSCREEN : String = "fullScreen" [static] Defines the value of the type property of a fullScreen event object. | Event
|  | ID3 : String = "id3" [static] Defines the value of the type property of an id3 event object. | Event
|  | INIT : String = "init" [static] Defines the value of the type property of an init event object. | Event
|  | MOUSE_LEAVE : String = "mouseLeave" [static] Defines the value of the type property of a mouseLeave event object. | Event
|  | OPEN : String = "open" [static] Defines the value of the type property of an open event object. | Event
|  | PASTE : String = "paste" [static] Defines the value of the type property of a paste event object. | Event
|  | REMOVED : String = "removed" [static] Defines the value of the type property of a removed event object. | Event
|  | REMOVED_FROM_STAGE : String = "removedFromStage" [static] Defines the value of the type property of a removedFromStage event object. | Event
|  | RENDER : String = "render" [static] Defines the value of the type property of a render event object. | Event
|  | RESIZE : String = "resize" [static] Defines the value of the type property of a resize event object. | Event
|  | SAMPLE_DATA : String = "sampleData" [static] Defines the value of the type property of a sampleData event object. | Event
|  | SCROLL : String = "scroll" [static] Defines the value of the type property of a scroll event object. | Event
|  | SELECT : String = "select" [static] Defines the value of the type property of a select event object. | Event
|  | SELECT_ALL : String = "selectAll" [static] Defines the value of the type property of a selectAll event object. | Event
|  | SOUND_COMPLETE : String = "soundComplete" [static] Defines the value of the type property of a soundComplete event object. | Event
|  | TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] Defines the value of the type property of a tabChildrenChange event object. | Event
|  | TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] Defines the value of the type property of a tabEnabledChange event object. | Event
|  | TAB_INDEX_CHANGE : String = "tabIndexChange" [static] Defines the value of the type property of a tabIndexChange event object. | Event
|  | UNLOAD : String = "unload" [static] Defines the value of the type property of an unload event object. | Event

Property Detail

bubbles | property

`bubbles:Boolean` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Indicates whether an event is a bubbling event. If the event can bubble, this value is `true`; otherwise it is `false`.

When an event occurs, it moves through the three phases of the event flow: the capture phase, which flows from the top of the display list hierarchy to the node just before the target node; the target phase, which comprises the target node; and the bubbling phase, which flows from the node subsequent to the target node back up the display list hierarchy.

Some events, such as the `activate` and `unload` events, do not have a bubbling phase. The `bubbles` property has a value of `false` for events that do not have a bubbling phase.

Implementation
`public function get bubbles():Boolean`

See also

Event objects

cancelable | property |

`cancelable:Boolean` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Indicates whether the behavior associated with the event can be prevented. If the behavior can be canceled, this value is `true`; otherwise it is `false`.

Implementation
`public function get cancelable():Boolean`

See also

Event.preventDefault()
Event objects

currentTarget | property |

`currentTarget:Object` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The object that is actively processing the Event object with an event listener. For example, if a user clicks an OK button, the current target could be the node containing that button or one of its ancestors that has registered an event listener for that event.

Implementation
`public function get currentTarget():Object`

See also

Event objects

eventPhase | property |

`eventPhase:uint` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The current phase in the event flow. This property can contain the following numeric values:

- 1 The capture phase (`EventPhase.CAPTURING_PHASE`).
- 2 The target phase (`EventPhase.AT_TARGET`).
- 3 The bubbling phase (`EventPhase.BUBBLING_PHASE`).

Implementation
`public function get eventPhase():uint`

See also

Event objects

target | property |

`target:Object` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The event target. This property contains the target node. For example, if a user clicks an OK button, the target node is the display list node containing that button.

Implementation
`public function get target():Object`

See also

Event objects

type | property |

`type:String` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The type of event. The type is case-sensitive.

Implementation
`public function get type():String`

See also

Event objects
Constructor Detail

Event | () | Constructor

`public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Creates an Event object to pass as a parameter to event listeners.

Parameters

| `type:String` — The type of the event, accessible as `Event.type`.
| `bubbles:Boolean` (default = `false`)`` — Determines whether the Event object participates in the bubbling stage of the event flow. The default value is `false`.
| `cancelable:Boolean` (default = `false`)`` — Determines whether the Event object can be canceled. The default values is `false`.

Method Detail

clone | () | method

`public function clone():Event`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Duplicates an instance of an Event subclass.

Returns a new Event object that is a copy of the original instance of the Event object. You do not normally call `clone()`; the EventDispatcher class calls it automatically when you redispatch an event—that is, when you call `dispatchEvent(event)` from a handler that is handling `event`.

The new Event object includes all the properties of the original.

When creating your own custom Event class, you must override the inherited `Event.clone()` method in order for it to duplicate the properties of your custom class. If you do not set all the properties that you add in your event subclass, those properties will not have the correct values when listeners handle the redispatched event.

In this example, `PingEvent` is a subclass of `Event` and therefore implements its own version of `clone()`.

      class PingEvent extends Event {
       var URL:String;

      public override function clone():Event {
            return new PingEvent(type, bubbles, cancelable, URL);
         }
      }

Returns

| `Event` — A new Event object that is identical to the original.

See also

Event objects

formatToString | () | method |

`public function formatToString(className:String, ... arguments):String`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

A utility function for implementing the `toString()` method in your custom Event class. Overriding the `toString()` method is recommended, but not required.

      class PingEvent extends Event {
       var URL:String;

      public override function toString():String {
       return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL");
         }
      }

Parameters

| `className:String` — The name of your custom Event class. In the previous example, the `className` parameter is `PingEvent`.
| `... arguments` — The properties of the Event class and the properties that you add in your custom Event class. In the previous example, the `...arguments` parameter includes `type`, `bubbles`, `cancelable`, `eventPhase`, and `URL`.

Returns

| `String` — The name of your custom Event class and the String value of your `...arguments` parameter.

isDefaultPrevented | () | method |

`public function isDefaultPrevented():Boolean`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Checks whether `preventDefault()` has been called on the event. If `preventDefault()` has been called, returns `true`; otherwise, returns `false`.

Returns

| `Boolean` — If `preventDefault()` has been called, returns `true`; otherwise, returns `false`.

See also

flash.events.Event.preventDefault()
Event objects

preventDefault | () | method |

`public function preventDefault():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Cancels an event's default behavior if that behavior can be canceled.

Many events have associated behaviors that Flash Player carries out by default. For example, if a user types a character into a text field, the default behavior is that the character is displayed in the text field. Because the `TextEvent.TEXT_INPUT` event's default behavior can be canceled, you can use the `preventDefault()` method to prevent the character from appearing.

An example of a behavior that is not cancelable is the default behavior associated with the `Event.REMOVED` event, which is generated whenever Flash Player is about to remove a display object from the display list. The default behavior (removing the element) cannot be canceled, so the `preventDefault()` method has no effect on this default behavior.

You can use the `Event.cancelable` property to check whether you can prevent the default behavior associated with a particular event. If the value of `Event.cancelable` is `true`, then `preventDefault()` can be used to cancel the event; otherwise, `preventDefault()` has no effect.

See also

flash.events.Event.isDefaultPrevented()
Event.cancelable
Event objects

stopImmediatePropagation | () | method |

`public function stopImmediatePropagation():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Prevents processing of any event listeners in the current node and any subsequent nodes in the event flow. This method takes effect immediately, and it affects event listeners in the current node. In contrast, the `stopPropagation()` method doesn't take effect until all the event listeners in the current node finish processing.

Note: This method does not cancel the behavior associated with this event; see `preventDefault()` for that functionality.

See also

flash.events.Event.stopPropagation()
flash.events.Event.preventDefault()
Event objects

stopPropagation | () | method |

`public function stopPropagation():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Prevents processing of any event listeners in nodes subsequent to the current node in the event flow. This method does not affect any event listeners in the current node (`currentTarget`). In contrast, the `stopImmediatePropagation()` method prevents processing of event listeners in both the current node and subsequent nodes. Additional calls to this method have no effect. This method can be called in any phase of the event flow.

Note: This method does not cancel the behavior associated with this event; see `preventDefault()` for that functionality.

See also

flash.events.Event.stopImmediatePropagation()
flash.events.Event.preventDefault()

toString | () | method |

`public function toString():String`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Returns a string containing all the properties of the Event object. The string is in the following format:

`[Event type=value bubbles=value cancelable=value]`

Returns

| `String` — A string containing all the properties of the Event object.

See also

Event objects
Constant Detail

ACTIVATE | Constant

`public static const ACTIVATE:String = "activate"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `activate` event object.

Note: This event does not go through a "capture phase" and is dispatched directly to the target, whether the target is on the display list or not.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any DisplayObject instance with a listener registered for the `activate` event.

See also

flash.events.EventDispatcher.activate
DEACTIVATE

ADDED | Constant |

`public static const ADDED:String = "added"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `added` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `true`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The DisplayObject instance being added to the display list. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.display.DisplayObject.added
ADDED_TO_STAGE
REMOVED
REMOVED_FROM_STAGE

ADDED_TO_STAGE | Constant |

`public static const ADDED_TO_STAGE:String = "addedToStage"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9.0.28.0

Defines the value of the `type` property of an `addedToStage` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The DisplayObject instance being added to the on stage display list, either directly or through the addition of a sub tree in which the DisplayObject instance is contained. If the DisplayObject instance is being directly added, the `added` event occurs before this event.

See also

flash.display.DisplayObject.addedToStage
ADDED
REMOVED
REMOVED_FROM_STAGE

CANCEL | Constant |

`public static const CANCEL:String = "cancel"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `cancel` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | A reference to the object on which the operation is canceled.

See also

flash.net.FileReference.cancel

CHANGE | Constant |

`public static const CHANGE:String = "change"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `change` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `true`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object that has had its value modified. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.text.TextField.change
flash.events.TextEvent.TEXT_INPUT

CLEAR | Constant |

`public static const CLEAR:String = "clear"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Defines the value of the `type` property of a `clear` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any InteractiveObject instance with a listener registered for the `clear` event.

See also

flash.events.InteractiveObject.clear

CLOSE | Constant |

`public static const CLOSE:String = "close"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `close` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object whose connection has been closed.

See also

flash.net.Socket.close
flash.net.XMLSocket.close

COMPLETE | Constant |

`public static const COMPLETE:String = "complete"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `complete` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The network object that has completed loading.

See also

flash.display.LoaderInfo.complete
flash.media.Sound.complete
flash.net.FileReference.complete
flash.net.URLLoader.complete
flash.net.URLStream.complete
Working with external data

CONNECT | Constant |

`public static const CONNECT:String = "connect"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `connect` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Socket or XMLSocket object that has established a network connection.

See also

flash.net.Socket.connect
flash.net.XMLSocket.connect

COPY | Constant |

`public static const COPY:String = "copy"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Defines the value of the `type` property of a `copy` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any InteractiveObject instance with a listener registered for the `copy` event.

See also

flash.events.InteractiveObject.copy

CUT | Constant |

`public static const CUT:String = "cut"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Defines the value of the `type` property of a `cut` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any InteractiveObject instance with a listener registered for the `cut` event.

See also

flash.events.InteractiveObject.cut

DEACTIVATE | Constant |

`public static const DEACTIVATE:String = "deactivate"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `deactivate` event object.

Note: This event does not go through a "capture phase" and is dispatched directly to the target, whether the target is on the display list or not.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any DisplayObject instance with a listener registered for the `deactivate` event.

See also

flash.events.EventDispatcher.deactivate
ACTIVATE

ENTER_FRAME | Constant |

`public static const ENTER_FRAME:String = "enterFrame"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `enterFrame` event object.

Note: This event does not go through a "capture phase" and is dispatched directly to the target, whether the target is on the display list or not.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any DisplayObject instance with a listener registered for the `enterFrame` event.

See also

flash.display.DisplayObject.enterFrame

EXIT_FRAME | Constant |

`public static const EXIT_FRAME:String = "exitFrame"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `exitFrame` event object.

Note: This event does not go through a "capture phase" and is dispatched directly to the target, whether the target is on the display list or not.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any DisplayObject instance with a listener registered for the `enterFrame` event.

See also

flash.display.DisplayObject.exitFrame

FRAME_CONSTRUCTED | Constant |

`public static const FRAME_CONSTRUCTED:String = "frameConstructed"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `frameConstructed` event object.

Note: This event does not go through a capture phase, and it is dispatched directly to the target, whether the target is on the display list or not.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any DisplayObject instance with a listener registered for the `frameConstructed` event.

See also

flash.display.DisplayObject.frameConstructed

FULLSCREEN | Constant |

`public static const FULLSCREEN:String = "fullScreen"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `fullScreen` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Stage object.

See also

flash.display.Stage.fullScreen

ID3 | Constant |

`public static const ID3:String = "id3"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `id3` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Sound object loading the MP3 for which ID3 data is now available. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.media.Sound.id3

INIT | Constant |

`public static const INIT:String = "init"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `init` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The LoaderInfo object associated with the SWF file being loaded.

See also

flash.display.LoaderInfo.init

MOUSE_LEAVE | Constant |

`public static const MOUSE_LEAVE:String = "mouseLeave"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `mouseLeave` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Stage object. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.display.Stage.mouseLeave
flash.events.MouseEvent

OPEN | Constant |

`public static const OPEN:String = "open"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `open` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The network object that has opened a connection.

See also

flash.display.LoaderInfo.open
flash.media.Sound.open
flash.net.FileReference.open
flash.net.URLLoader.open
flash.net.URLStream.open

PASTE | Constant |

`public static const PASTE:String = "paste"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Defines the value of the `type` property of a `paste` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any InteractiveObject instance with a listener registered for the `paste` event.

See also

flash.events.InteractiveObject.paste

REMOVED | Constant |

`public static const REMOVED:String = "removed"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `removed` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `true`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The DisplayObject instance to be removed from the display list. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.display.DisplayObject.removed
ADDED
ADDED_TO_STAGE
REMOVED_FROM_STAGE

REMOVED_FROM_STAGE | Constant |

`public static const REMOVED_FROM_STAGE:String = "removedFromStage"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9.0.28.0

Defines the value of the `type` property of a `removedFromStage` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The DisplayObject instance being removed from the on stage display list, either directly or through the removal of a sub tree in which the DisplayObject instance is contained. If the DisplayObject instance is being directly removed, the `removed` event occurs before this event.

See also

flash.display.DisplayObject.removedFromStage
ADDED
REMOVED
ADDED_TO_STAGE

RENDER | Constant |

`public static const RENDER:String = "render"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `render` event object.

Note: This event does not go through a "capture phase" and is dispatched directly to the target, whether the target is on the display list or not.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; the default behavior cannot be canceled.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any DisplayObject instance with a listener registered for the `render` event.

See also

flash.display.DisplayObject.render
flash.display.Stage.invalidate()

RESIZE | Constant |

`public static const RESIZE:String = "resize"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `resize` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Stage object.

See also

flash.display.Stage.resize

SAMPLE_DATA | Constant |

`public static const SAMPLE_DATA:String = "sampleData"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Defines the value of the `type` property of a `sampleData` event object.

See also

flash.media.Sound.sampleData

SCROLL | Constant |

`public static const SCROLL:String = "scroll"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `scroll` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The TextField object that has been scrolled. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.text.TextField.scroll

SELECT | Constant |

`public static const SELECT:String = "select"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `select` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The FileReference object on which an item has been selected.

See also

flash.net.FileReference.select

SELECT_ALL | Constant |

`public static const SELECT_ALL:String = "selectAll"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

Defines the value of the `type` property of a `selectAll` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | Any InteractiveObject instance with a listener registered for the `selectAll` event.

See also

flash.events.InteractiveObject.selectAll

SOUND_COMPLETE | Constant |

`public static const SOUND_COMPLETE:String = "soundComplete"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `soundComplete` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Sound object on which a sound has finished playing.

See also

flash.media.SoundChannel.soundComplete

TAB_CHILDREN_CHANGE | Constant |

`public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `tabChildrenChange` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `true`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object whose tabChildren flag has changed. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.display.InteractiveObject.tabChildrenChange

TAB_ENABLED_CHANGE | Constant |

`public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `tabEnabledChange` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `true`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The InteractiveObject whose tabEnabled flag has changed. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.display.InteractiveObject.tabEnabledChange

TAB_INDEX_CHANGE | Constant |

`public static const TAB_INDEX_CHANGE:String = "tabIndexChange"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of a `tabIndexChange` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `true`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object whose tabIndex has changed. The `target` is not always the object in the display list that registered the event listener. Use the `currentTarget` property to access the object in the display list that is currently processing the event.

See also

flash.display.InteractiveObject.tabIndexChange

UNLOAD | Constant |

`public static const UNLOAD:String = "unload"`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Defines the value of the `type` property of an `unload` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The LoaderInfo object associated with the SWF file being unloaded or replaced.

See also

flash.display.LoaderInfo.unload
Examples How to use examples
EventExample.as
The following example uses the `EventExample` class and the `Square` custom class to demonstrate how to manage event bubbling.

    package {
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;

        public class EventExample extends Sprite {

            public function EventExample() {
                var square_0:Square = new Square(300, 0x336633);
                addChild(square_0);

                var square_1:Square = new Square(250, 0x669966);
                square_0.addChild(square_1);

                var square_2:Square = new Square(200, 0x66CC66);
                square_1.addChild(square_2);

                var square_3:Square = new Square(150, 0xAA0000);
                square_3.shouldBubble = false;
                square_2.addChild(square_3);

                var square_4:Square = new Square(100, 0x66FF66);
                square_3.addChild(square_4);

                var square_5:Square = new Square(50, 0xCC0000);
                square_5.shouldBubble = false;
                square_4.addChild(square_5);

                this.addEventListener(MouseEvent.CLICK, clickHandler);
            }

            private function clickHandler(e:Event):void {
                trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
                trace(">> --------------------------------------------");
            }
        }
    }

    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    class Square extends Sprite {
        private var sideLen:int;
        private var color:Number;
        public var shouldBubble:Boolean = true;

        public function Square(sideLen:int, color:Number) {
            this.sideLen = sideLen;
            this.color = color;
            init();
            draw();
        }

        private function init():void {
            buttonMode = true;
            this.addEventListener(MouseEvent.CLICK, firstClickHandler);
            this.addEventListener(MouseEvent.CLICK, secondClickHandler);
            this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
        }

        private function draw():void {
            this.graphics.beginFill(color);
            this.graphics.drawRect(0, 0, sideLen, sideLen);
        }

        private function firstClickHandler(e:Event):void {
            trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
            if(!shouldBubble) {
                e.stopPropagation();
            }
        }

        private function secondClickHandler(e:Event):void {
            trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
            if(!shouldBubble) {
                e.stopImmediatePropagation();
                trace(">> --------------------------------------------");
            }
        }

        private function thirdClickHandler(e:Event):void {
            trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        }
    }

EventExample2.as
The following example creates an interactive demonstration of the difference between `ADDED` and `ADDED_TO_STAGE` events, as well as the difference between `REMOVED` and `REMOVED_FROM_STAGE` events. Clicking a sprite will remove it from the stage as well as everything nested within it. For example, clicking the largest sprite will cause a `REMOVED` event as well as three `REMOVED_FROM_STAGE` events to fire.

     package {
        import flash.display.Sprite;
        import flash.events.*;

        public class EventExample2 extends Sprite {
            public function EventExample2():void {
                var parentSprite:Sprite = createSprite("parentSprite",200);
                var childSprite:Sprite = createSprite("childSprite",100);
                var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);

                trace(":: Adding to Stage ::");
                this.addChild(parentSprite);
                trace(":: Adding to Stage ::");
                parentSprite.addChild(childSprite);
                trace(":: Adding to Stage ::");
                childSprite.addChild(childOfChildSprite);
            }
            private function createSprite(name:String,size:uint):Sprite {
                trace(":: Creating Sprite ::");
                var newSprite:Sprite = new Sprite();
                newSprite.name = name;
                newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
                newSprite.graphics.drawRect(0,0,size,size);
                newSprite.graphics.endFill();
                newSprite.addEventListener(Event.ADDED, spriteAdded);
                newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
                newSprite.addEventListener(Event.REMOVED, spriteRemoved);
                newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
                newSprite.addEventListener(MouseEvent.CLICK, remove);
                return newSprite;
            }
            private function remove(event:Event) {
                if(event.target == event.currentTarget) {
                    trace(":: Removing Clicked Sprite ::");
                    var target:Sprite = Sprite(event.target);
                    target.parent.removeChild(target);
                }
            }
            private function spriteRemovedFromStage(event:Event):void {
                trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
            }
            private function spriteRemoved(event:Event):void {
                trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
            }
            private function spriteAddedToStage(event:Event):void {
                trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
            }
            private function spriteAdded(event:Event):void {
                trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
            }
        }
    }

Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Tue May 20 2008, 04:02 AM -07:00