ActionScript 3.0 Language and Components Reference | All Packages | All Classes | Language Elements | Index | Appendixes | Conventions | Frames No Frames |
MovieClip

Package | flash.display
Class | public dynamic class MovieClip
Inheritance | MovieClip Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The MovieClip class inherits from the following classes: Sprite, DisplayObjectContainer, InteractiveObject, DisplayObject, and EventDispatcher.

Unlike the Sprite object, a MovieClip object has a timeline.

The methods for the MovieClip class provide the same functionality as actions that target movie clips. Some additional methods do not have equivalent actions in the Actions toolbox in the Actions panel in the Flash authoring tool.

Children instances placed on the Stage in the Flash authoring tool cannot be accessed by code from within the constructor of a parent instance since they have not been created at that point in code execution. Before accessing the child, the parent must instead either create the child instance by code or delay access to a callback function that listens for the child to dispatch its `Event.ADDED_TO_STAGE` event.

If you modify any of the following properties of a MovieClip object that contains a motion tween, Flash Player stops the playhead in that MovieClip object: `alpha`, `blendMode`, `filters`, `height`, `opaqueBackground`, `rotation`, `scaleX`, `scaleY`, `scale9Grid`, `scrollRect`, `transform`, `visible`, `width`, `x`, or `y`. However, it does not stop the playhead in any child MovieClip objects of that MovieClip object.

View the examples

See also

Core display classes
Basics of movie clips

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | accessibilityProperties : AccessibilityProperties The current accessibility options for this display object. | DisplayObject
|  | alpha : Number Indicates the alpha transparency value of the object specified. | DisplayObject
|  | blendMode : String A value from the BlendMode class that specifies which blend mode to use. | DisplayObject
|  | buttonMode : Boolean Specifies the button mode of this sprite. | Sprite
|  | cacheAsBitmap : Boolean If set to true, Flash Player caches an internal bitmap representation of the display object. | DisplayObject
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | contextMenu : ContextMenu Specifies the context menu associated with this object. | InteractiveObject
|  | currentFrame : int [read-only] Specifies the number of the frame in which the playhead is located in the timeline of the MovieClip instance. | MovieClip
|  | currentFrameLabel : String [read-only] The label at the current frame in the timeline of the MovieClip instance. | MovieClip
|  | currentLabel : String [read-only] The current label in which the playhead is located in the timeline of the MovieClip instance. | MovieClip
|  | currentLabels : Array [read-only] Returns an array of FrameLabel objects from the current scene. | MovieClip
|  | currentScene : Scene [read-only] The current scene in which the playhead is located in the timeline of the MovieClip instance. | MovieClip
|  | doubleClickEnabled : Boolean Specifies whether the object receives doubleClick events. | InteractiveObject
|  | dropTarget : DisplayObject [read-only] Specifies the display object over which the sprite is being dragged, or on which the sprite was dropped. | Sprite
|  | enabled : Boolean A Boolean value that indicates whether a movie clip is enabled. | MovieClip
|  | filters : Array An indexed array that contains each filter object currently associated with the display object. | DisplayObject
|  | focusRect : Object Specifies whether this object displays a focus rectangle. | InteractiveObject
|  | framesLoaded : int [read-only] The number of frames that are loaded from a streaming SWF file. | MovieClip
|  | graphics : Graphics [read-only] Specifies the Graphics object that belongs to this sprite where vector drawing commands can occur. | Sprite
|  | height : Number Indicates the height of the display object, in pixels. | DisplayObject
|  | hitArea : Sprite Designates another sprite to serve as the hit area for a sprite. | Sprite
|  | loaderInfo : LoaderInfo [read-only] Returns a LoaderInfo object containing information about loading the file to which this display object belongs. | DisplayObject
|  | mask : DisplayObject The calling display object is masked by the specified mask object. | DisplayObject
|  | mouseChildren : Boolean Determines whether or not the children of the object are mouse enabled. | DisplayObjectContainer
|  | mouseEnabled : Boolean Specifies whether this object receives mouse messages. | InteractiveObject
|  | mouseX : Number [read-only] Indicates the x coordinate of the mouse position, in pixels. | DisplayObject
|  | mouseY : Number [read-only] Indicates the y coordinate of the mouse position, in pixels. | DisplayObject
|  | name : String Indicates the instance name of the DisplayObject. | DisplayObject
|  | numChildren : int [read-only] Returns the number of children of this object. | DisplayObjectContainer
|  | opaqueBackground : Object Specifies whether the display object is opaque with a certain background color. | DisplayObject
|  | parent : DisplayObjectContainer [read-only] Indicates the DisplayObjectContainer object that contains this display object. | DisplayObject
|  | prototype : Object [static] A reference to the prototype object of a class or function object. | Object
|  | root : DisplayObject [read-only] For a display object in a loaded SWF file, the root property is the top-most display object in the portion of the display list's tree structure represented by that SWF file. | DisplayObject
|  | rotation : Number Indicates the rotation of the DisplayObject instance, in degrees, from its original orientation. | DisplayObject
|  | scale9Grid : Rectangle The current scaling grid that is in effect. | DisplayObject
|  | scaleX : Number Indicates the horizontal scale (percentage) of the object as applied from the registration point. | DisplayObject
|  | scaleY : Number Indicates the vertical scale (percentage) of an object as applied from the registration point of the object. | DisplayObject
|  | scenes : Array [read-only] An array of Scene objects, each listing the name, the number of frames, and the frame labels for a scene in the MovieClip instance. | MovieClip
|  | scrollRect : Rectangle The scroll rectangle bounds of the display object. | DisplayObject
|  | soundTransform : SoundTransform Controls sound within this sprite. | Sprite
|  | stage : Stage [read-only] The Stage of the display object. | DisplayObject
|  | tabChildren : Boolean Determines whether the children of the object are tab enabled. | DisplayObjectContainer
|  | tabEnabled : Boolean Specifies whether this object is in the tab order. | InteractiveObject
|  | tabIndex : int Specifies the tab ordering of objects in a SWF file. | InteractiveObject
|  | textSnapshot : TextSnapshot [read-only] Returns a TextSnapshot object for this DisplayObjectContainer instance. | DisplayObjectContainer
|  | totalFrames : int [read-only] The total number of frames in the MovieClip instance. | MovieClip
|  | trackAsMenu : Boolean Indicates whether other display objects that are SimpleButton or MovieClip objects can receive mouse release events. | MovieClip
|  | transform : Transform An object with properties pertaining to a display object's matrix, color transform, and pixel bounds. | DisplayObject
|  | useHandCursor : Boolean A Boolean value that indicates whether the pointing hand (hand cursor) appears when the mouse rolls over a sprite in which the buttonMode property is set to true. | Sprite
|  | visible : Boolean Whether or not the display object is visible. | DisplayObject
|  | width : Number Indicates the width of the display object, in pixels. | DisplayObject
|  | x : Number Indicates the x coordinate of the DisplayObject instance relative to the local coordinates of the parent DisplayObjectContainer. | DisplayObject
|  | y : Number Indicates the y coordinate of the DisplayObject instance relative to the local coordinates of the parent DisplayObjectContainer. | DisplayObject

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | MovieClip() Creates a new MovieClip instance. | MovieClip
|  | addChild(child:DisplayObject):DisplayObject Adds a child DisplayObject instance to this DisplayObjectContainer instance. | DisplayObjectContainer
|  | addChildAt(child:DisplayObject, index:int):DisplayObject Adds a child DisplayObject instance to this DisplayObjectContainer instance. | DisplayObjectContainer
|  | addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registers an event listener object with an EventDispatcher object so that the listener receives notification of an event. | EventDispatcher
|  | areInaccessibleObjectsUnderPoint(point:Point):Boolean Indicates whether the security restrictions would cause any display objects to be omitted from the list returned by calling the DisplayObjectContainer.getObjectsUnderPoint() method with the specified point point. | DisplayObjectContainer
|  | contains(child:DisplayObject):Boolean Determines whether the specified display object is a child of the DisplayObjectContainer instance or the instance itself. | DisplayObjectContainer
|  | dispatchEvent(event:Event):Boolean Dispatches an event into the event flow. | EventDispatcher
|  | getBounds(targetCoordinateSpace:DisplayObject):Rectangle Returns a rectangle that defines the area of the display object relative to the coordinate system of the targetCoordinateSpace object. | DisplayObject
|  | getChildAt(index:int):DisplayObject Returns the child display object instance that exists at the specified index. | DisplayObjectContainer
|  | getChildByName(name:String):DisplayObject Returns the child display object that exists with the specified name. | DisplayObjectContainer
|  | getChildIndex(child:DisplayObject):int Returns the index position of a child DisplayObject instance. | DisplayObjectContainer
|  | getObjectsUnderPoint(point:Point):Array Returns an array of objects that lie under the specified point and are children (or grandchildren, and so on) of this DisplayObjectContainer instance. | DisplayObjectContainer
|  | getRect(targetCoordinateSpace:DisplayObject):Rectangle Returns a rectangle that defines the boundary of the display object, based on the coordinate system defined by the targetCoordinateSpace parameter, excluding any strokes on shapes. | DisplayObject
|  | globalToLocal(point:Point):Point Converts the point object from the Stage (global) coordinates to the display object's (local) coordinates. | DisplayObject
|  | gotoAndPlay(frame:Object, scene:String = null):void Starts playing the SWF file at the specified frame. | MovieClip
|  | gotoAndStop(frame:Object, scene:String = null):void Brings the playhead to the specified frame of the movie clip and stops it there. | MovieClip
|  | hasEventListener(type:String):Boolean Checks whether the EventDispatcher object has any listeners registered for a specific type of event. | EventDispatcher
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | hitTestObject(obj:DisplayObject):Boolean Evaluates the display object to see if it overlaps or intersects with the obj display object. | DisplayObject
|  | hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean Evaluates the display object to see if it overlaps or intersects with the point specified by the x and y parameters. | DisplayObject
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | localToGlobal(point:Point):Point Converts the point object from the display object's (local) coordinates to the Stage (global) coordinates. | DisplayObject
|  | nextFrame():void Sends the playhead to the next frame and stops it. | MovieClip
|  | nextScene():void Moves the playhead to the next scene of the MovieClip instance. | MovieClip
|  | play():void Moves the playhead in the timeline of the movie clip. | MovieClip
|  | prevFrame():void Sends the playhead to the previous frame and stops it. | MovieClip
|  | prevScene():void Moves the playhead to the previous scene of the MovieClip instance. | MovieClip
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | removeChild(child:DisplayObject):DisplayObject Removes the specified child DisplayObject instance from the child list of the DisplayObjectContainer instance. | DisplayObjectContainer
|  | removeChildAt(index:int):DisplayObject Removes a child DisplayObject from the specified index position in the child list of the DisplayObjectContainer. | DisplayObjectContainer
|  | removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Removes a listener from the EventDispatcher object. | EventDispatcher
|  | setChildIndex(child:DisplayObject, index:int):void Changes the position of an existing child in the display object container. | DisplayObjectContainer
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void Lets the user drag the specified sprite. | Sprite
|  | stop():void Stops the playhead in the movie clip. | MovieClip
|  | stopDrag():void Ends the startDrag() method. | Sprite
|  | swapChildren(child1:DisplayObject, child2:DisplayObject):void Swaps the z-order (front-to-back order) of the two specified child objects. | DisplayObjectContainer
|  | swapChildrenAt(index1:int, index2:int):void Swaps the z-order (front-to-back order) of the child objects at the two specified index positions in the child list. | DisplayObjectContainer
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object
|  | willTrigger(type:String):Boolean Checks whether an event listener is registered with this EventDispatcher object or any of its ancestors for the specified event type. | EventDispatcher

Events
Hide Inherited Events
Show Inherited Events

| Event | Summary | Defined By
--- | --- | --- | ---
|  | activate | Dispatched when Flash Player gains operating system focus and becomes active. | EventDispatcher
|  | added | Dispatched when a display object is added to the display list. | DisplayObject
|  | addedToStage | Dispatched when a display object is added to the on stage display list, either directly or through the addition of a sub tree in which the display object is contained. | DisplayObject
|  | clear | Dispatched when the user selects 'Clear' (or 'Delete') from the text context menu. | InteractiveObject
|  | click | Dispatched when a user presses and releases the main button of the user's pointing device over the same InteractiveObject. | InteractiveObject
|  | copy | Dispatched when the user activates the platform specific accelerator key combination for a copy operation or selects 'Copy' from the text context menu. | InteractiveObject
|  | cut | Dispatched when the user activates the platform specific accelerator key combination for a cut operation or selects 'Cut' from the text context menu. | InteractiveObject
|  | deactivate | Dispatched when Flash Player loses operating system focus and is becoming inactive. | EventDispatcher
|  | doubleClick | Dispatched when a user presses and releases the main button of a pointing device twice in rapid succession over the same InteractiveObject when that object's doubleClickEnabled flag is set to true. | InteractiveObject
|  | enterFrame | Dispatched when the playhead is entering a new frame. | DisplayObject
|  | exitFrame | Dispatched when the playhead is exiting the current frame. | DisplayObject
|  | focusIn | Dispatched after a display object gains focus. | InteractiveObject
|  | focusOut | Dispatched after a display object loses focus. | InteractiveObject
|  | frameConstructed | Dispatched after the constructors of frame display objects have run but before frame scripts have run. | DisplayObject
|  | keyDown | Dispatched when the user presses a key. | InteractiveObject
|  | keyFocusChange | Dispatched when the user attempts to change focus by using keyboard navigation. | InteractiveObject
|  | keyUp | Dispatched when the user releases a key. | InteractiveObject
|  | mouseDown | Dispatched when a user presses the pointing device button over an InteractiveObject instance in the Flash Player window. | InteractiveObject
|  | mouseFocusChange | Dispatched when the user attempts to change focus by using a pointer device. | InteractiveObject
|  | mouseMove | Dispatched when a user moves the pointing device while it is over an InteractiveObject. | InteractiveObject
|  | mouseOut | Dispatched when the user moves a pointing device away from an InteractiveObject instance. | InteractiveObject
|  | mouseOver | Dispatched when the user moves a pointing device over an InteractiveObject instance in the Flash Player window. | InteractiveObject
|  | mouseUp | Dispatched when a user releases the pointing device button over an InteractiveObject instance in the Flash Player window. | InteractiveObject
|  | mouseWheel | Dispatched when a mouse wheel is spun over an InteractiveObject instance in the Flash Player window. | InteractiveObject
|  | paste | Dispatched when the user activates the platform specific accelerator key combination for a paste operation or selects 'Paste' from the text context menu. | InteractiveObject
|  | removed | Dispatched when a display object is about to be removed from the display list. | DisplayObject
|  | removedFromStage | Dispatched when a display object is about to be removed from the display list, either directly or through the removal of a sub tree in which the display object is contained. | DisplayObject
|  | render | Dispatched when the display list is about to be updated and rendered. | DisplayObject
|  | rollOut | Dispatched when the user moves a pointing device away from an InteractiveObject instance. | InteractiveObject
|  | rollOver | Dispatched when the user moves a pointing device over an InteractiveObject instance. | InteractiveObject
|  | selectAll | Dispatched when the user activates the platform specific accelerator key combination for a select all operation or selects 'Select All' from the text context menu. | InteractiveObject
|  | tabChildrenChange | Dispatched when the value of the object's tabChildren flag changes. | InteractiveObject
|  | tabEnabledChange | Dispatched when the object's tabEnabled flag changes. | InteractiveObject
|  | tabIndexChange | Dispatched when the value of the object's tabIndex property changes. | InteractiveObject

Property Detail

currentFrame | property

`currentFrame:int` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Specifies the number of the frame in which the playhead is located in the timeline of the MovieClip instance. If the movie clip has multiple scenes, this value is the frame number in the current scene.

Implementation
`public function get currentFrame():int`
Example
The following code uses the `gotoAndStop()` method and the `currentFrame` property to direct the playhead of the `mc1` movie clip to advance five frames ahead of its current location and stop:

    mc1.gotoAndStop(mc1.currentFrame + 5);

currentFrameLabel | property |

`currentFrameLabel:String` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 10

The label at the current frame in the timeline of the MovieClip instance. If the current frame has no label, `currentLabel` is `null`.

Implementation
`flash10 function get currentFrameLabel():String`

currentLabel | property |

`currentLabel:String` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The current label in which the playhead is located in the timeline of the MovieClip instance. If the current frame has no label, `currentLabel` is set to the name of the previous frame that includes a label. If the current frame and previous frames do not include a label, `currentLabel` returns `null`.

Implementation
`public function get currentLabel():String`
Example
The following code illustrates how to access the `currentLabel` property of a MovieClip object named `mc1`:

    trace(mc1.currentLabel);

currentLabels | property |

`currentLabels:Array` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Returns an array of FrameLabel objects from the current scene. If the MovieClip instance does not use scenes, the array includes all frame labels from the entire MovieClip instance.

Implementation
`public function get currentLabels():Array`

See also

flash.display.FrameLabel
Example
The following code illustrates how to use the `currentLabels` property of a MovieClip object named `mc1`:

    import flash.display.FrameLabel;

    var labels:Array = mc1.currentLabels;

    for (var i:uint = 0; i < labels.length; i++) {
        var label:FrameLabel = labels[i];
        trace("frame " + label.frame + ": " + label.name);
    }

currentScene | property |

`currentScene:Scene` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The current scene in which the playhead is located in the timeline of the MovieClip instance.

Implementation
`public function get currentScene():Scene`

See also

Scene
Example
The following code illustrates how to use the `currentScene` property of a MovieClip object named `mc1`:

    import flash.display.Scene;

    var scene:Scene = mc1.currentScene;
    trace(scene.name + ": " + scene.numFrames + " frames");

enabled | property |

`enabled:Boolean` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

A Boolean value that indicates whether a movie clip is enabled. The default value of `enabled` is `true`. If `enabled` is set to `false`, the movie clip's Over, Down, and Up frames are disabled. The movie clip continues to receive events (for example, `mouseDown`, `mouseUp`, `keyDown`, and `keyUp`).

The `enabled` property governs only the button-like properties of a movie clip. You can change the `enabled` property at any time; the modified movie clip is immediately enabled or disabled. If `enabled` is set to `false`, the object is not included in automatic tab ordering.

Implementation
`public function get enabled():Boolean`
`public function set enabled(value:Boolean):void`
Example
The following code illustrates how to use the `enabled` property to disable the button-like properties of a MovieClip object named `mc1`:

    mc1.enabled = false;

framesLoaded | property |

`framesLoaded:int` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The number of frames that are loaded from a streaming SWF file. You can use the `framesLoaded` property to determine whether the contents of a specific frame and all the frames before it loaded and are available locally in the browser. You can also use it to monitor the downloading of large SWF files. For example, you might want to display a message to users indicating that the SWF file is loading until a specified frame in the SWF file finishes loading.

If the movie clip contains multiple scenes, the `framesLoaded` property returns the number of frames loaded for all scenes in the movie clip.

Implementation
`public function get framesLoaded():int`

See also

Loader class
Example
The following code illustrates how to use the `framesLoaded` property and the `totalFrames` property to determine if a streaming MovieClip object named `mc1` is fully loaded:

    if (mc1.framesLoaded == mc1.totalFrames) {
        trace("OK.");
    }

scenes | property |

`scenes:Array` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

An array of Scene objects, each listing the name, the number of frames, and the frame labels for a scene in the MovieClip instance.

Implementation
`public function get scenes():Array`

See also

Scene
Example
The following code illustrates how to use the `scenes` property of a MovieClip object named `mc1`:

    import flash.display.Scene;

    for (var i:uint = 0; i < mc1.scenes.length; i++) {
        var scene:Scene = mc1.scenes[i];
        trace("scene " + scene.name + ": " + scene.numFrames + " frames");
    }

totalFrames | property |

`totalFrames:int` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The total number of frames in the MovieClip instance.

If the movie clip contains multiple frames, the `totalFrames` property returns the total number of frames in all scenes in the movie clip.

Implementation
`public function get totalFrames():int`
Example
The following code illustrates the use of the `totalFrames` property of a MovieClip object named `mc1`:

     trace(mc1.totalFrames);

trackAsMenu | property |

`trackAsMenu:Boolean` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Indicates whether other display objects that are SimpleButton or MovieClip objects can receive mouse release events. The `trackAsMenu` property lets you create menus. You can set the `trackAsMenu` property on any SimpleButton or MovieClip object. The default value of the `trackAsMenu` property is `false`.

You can change the `trackAsMenu` property at any time; the modified movie clip immediately uses the new behavior.

Implementation
`public function get trackAsMenu():Boolean`
`public function set trackAsMenu(value:Boolean):void`
Example
The following code illustrates how to use the `trackAsMenu` property to enable mouse release events for a MovieClip object named `mc1`:

     mc1.trackAsMenu = true;

Constructor Detail

MovieClip | () | Constructor

`public function MovieClip()`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Creates a new MovieClip instance. After creating the MovieClip, call the `addChild()` or `addChildAt()` method of a display object container that is onstage.

Method Detail

gotoAndPlay | () | method

`public function gotoAndPlay(frame:Object, scene:String = null):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Starts playing the SWF file at the specified frame. This happens after all remaining actions in the frame have finished executing. To specify a scene as well as a frame, specify a value for the `scene` parameter.

Parameters

| `frame:Object` — A number representing the frame number, or a string representing the label of the frame, to which the playhead is sent. If you specify a number, it is relative to the scene you specify. If you do not specify a scene, Flash Player uses the current scene to determine the global frame number to play. If you do specify a scene, the playhead jumps to the frame number in the specified scene.
| `scene:String` (default = `null`)`` — The name of the scene to play. This parameter is optional.

Example
The following code uses the `gotoAndPlay()` method to direct the playhead of the `mc1` movie clip to advance five frames ahead of its current location:

    mc1.gotoAndPlay(mc1.currentFrame + 5);

The following code uses the `gotoAndPlay()` method to direct the playhead of the `mc1` movie clip to the frame labeled `"intro"` in the scene named `"Scene 12"`:

    mc1.gotoAndPlay("intro", "Scene 12");

gotoAndStop | () | method |

`public function gotoAndStop(frame:Object, scene:String = null):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Brings the playhead to the specified frame of the movie clip and stops it there. This happens after all remaining actions in the frame have finished executing. If you want to specify a scene in addition to a frame, specify a `scene` parameter.

Parameters

| `frame:Object` — A number representing the frame number, or a string representing the label of the frame, to which the playhead is sent. If you specify a number, it is relative to the scene you specify. If you do not specify a scene, Flash Player uses the current scene to determine the global frame number at which to go to and stop. If you do specify a scene, the playhead goes to the frame number in the specified scene and stops.
| `scene:String` (default = `null`)`` — The name of the scene. This parameter is optional.

Throws

| `ArgumentError` — If the `scene` or `frame` specified are not found in this movie clip.

Example
The following code uses the `gotoAndStop()` method and the `currentFrame` property to direct the playhead of the `mc1` movie clip to advance five frames ahead of its current location and stop:

    mc1.gotoAndStop(mc1.currentFrame + 5);

The following code uses the `gotoAndStop()` to direct the playhead of the `mc1` movie clip to the frame labeled `"finale"` in the scene named `"Scene 12"` and stop the playhead:

    mc1.gotoAndStop("finale", "Scene 12");

nextFrame | () | method |

`public function nextFrame():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Sends the playhead to the next frame and stops it. This happens after all remaining actions in the frame have finished executing.

See also

prevFrame()
Example
In the following example, two SimpleButton objects control the timeline. The `prev` button moves the playhead to the previous frame, and the `nextBtn` button moves the playhead to the next frame:

    import flash.events.MouseEvent;

    mc1.stop();
    prevBtn.addEventListener(MouseEvent.CLICK, goBack);
    nextBtn.addEventListener(MouseEvent.CLICK, goForward);

    function goBack(event:MouseEvent):void {
        mc1.prevFrame();
    }

    function goForward(event:MouseEvent):void {
        mc1.nextFrame();
    }

nextScene | () | method |

`public function nextScene():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Moves the playhead to the next scene of the MovieClip instance. This happens after all remaining actions in the frame have finished executing.

Example
In the following example, two SimpleButton objects control the timeline. The `prevBtn` button moves the playhead to the previous scene, and the `nextBtn` button moves the playhead to the next scene:

    import flash.events.MouseEvent;

    mc1.stop();
    prevBtn.addEventListener(MouseEvent.CLICK, goBack);
    nextBtn.addEventListener(MouseEvent.CLICK, goForward);

    function goBack(event:MouseEvent):void {
        mc1.prevScene();
    }

    function goForward(event:MouseEvent):void {
        mc1.nextScene();
    }

play | () | method |

`public function play():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Moves the playhead in the timeline of the movie clip.

See also

gotoAndPlay()
Example
The following code uses the `stop()` method to stop a movie clip named `mc1` and to resume playing when the user clicks the text field named `continueText`:

    import flash.text.TextField;
    import flash.events.MouseEvent;

    var continueText:TextField = new TextField();
    continueText.text = "Play movie...";
    addChild(continueText);

    mc1.stop();
    continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

    function resumeMovie(event:MouseEvent):void {
        mc1.play();
    }

prevFrame | () | method |

`public function prevFrame():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Sends the playhead to the previous frame and stops it. This happens after all remaining actions in the frame have finished executing.

Example
In the following example, two SimpleButton objects control the timeline. The `prev` button moves the playhead to the previous frame, and the `nextBtn` button moves the playhead to the next frame:

    import flash.events.MouseEvent;

    mc1.stop();
    prevBtn.addEventListener(MouseEvent.CLICK, goBack);
    nextBtn.addEventListener(MouseEvent.CLICK, goForward);

    function goBack(event:MouseEvent):void {
        mc1.prevFrame();
    }

    function goForward(event:MouseEvent):void {
        mc1.nextFrame();
    }

prevScene | () | method |

`public function prevScene():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Moves the playhead to the previous scene of the MovieClip instance. This happens after all remaining actions in the frame have finished executing.

Example
In the following example, two SimpleButton objects control the timeline. The `prevBtn` button moves the playhead to the previous scene, and the `nextBtn` button moves the playhead to the next scene:

    import flash.events.MouseEvent;

    mc1.stop();
    prevBtn.addEventListener(MouseEvent.CLICK, goBack);
    nextBtn.addEventListener(MouseEvent.CLICK, goForward);

    function goBack(event:MouseEvent):void {
        mc1.prevScene();
    }

    function goForward(event:MouseEvent):void {
        mc1.nextScene();
    }

stop | () | method |

`public function stop():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Stops the playhead in the movie clip.

Examples How to use examples
MovieClipExample.as
The following example uses the MovieClipExample class to illustrate how to monitor various properties of a MovieClip. This task is accomplished by performing the following steps:

1. The constructor function defines a text field, which is used to display values of properties of the MovieClipExample object (which extends MovieClip).
2. The return value of the `getPropertiesString()` method is used as text for the `outputText` text field. The `getPropertiesString()` method returns a string that is populated with values of the following properties of the movie clip: `currentFrame`, `currentLabel`, `currentScene`, `framesLoaded`, `totalFrames`, and `trackAsMenu`.
3. Two lines of code in the constructor function adjust the `width` and `height` properties of the `outputText` text field.
4. The last line of the constructor function adds the `outputText` text field to the display list.

    package {
        import flash.display.MovieClip;
        import flash.text.TextField;

        public class MovieClipExample extends MovieClip {

            public function MovieClipExample() {
                var outputText:TextField = new TextField();
                outputText.text = getPropertiesString();
                outputText.width = stage.stageWidth;
                outputText.height = outputText.textHeight;
                addChild(outputText);
            }

            private function getPropertiesString():String {
                var str:String = ""
                    + "currentFrame: " + currentFrame + "\n"
                    + "currentLabel: " + currentLabel + "\n"
                    + "currentScene: " + currentScene + "\n"
                    + "framesLoaded: " + framesLoaded + "\n"
                    + "totalFrames: " + totalFrames + "\n"
                    + "trackAsMenu: " + trackAsMenu + "\n";
                return str;
            }
        }
    }

Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Tue May 20 2008, 04:02 AM -07:00