ActionScript 3.0 Language and Components Reference | All Packages | All Classes | Language Elements | Index | Appendixes | Conventions | Frames No Frames |
Package

The flash.net package contains package-level functions for opening a new browser window, sending a URL request to a server, and dealing with class aliases.
Public Methods

| Function | Defined By
--- | --- | ---
|  | getClassByAlias() Looks up a class that previously had an alias registered through a call to the registerClassAlias() method. | flash.net
|  | navigateToURL(, = null) Opens or replaces a window in the application that contains the Flash Player container (usually a browser). | flash.net
|  | registerClassAlias(, ) Preserves the class (type) of an object when the object is encoded in Action Message Format (AMF). | flash.net
|  | sendToURL() Sends a URL request to a server, but ignores any response. | flash.net

Function detail

getClassByAlias | () |

`public getClassByAlias()`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Looks up a class that previously had an alias registered through a call to the `registerClassAlias()` method.

This method does not interact with the `flash.utils.getDefinitionByName()` method.

Parameters

| `aliasName` — The alias to find.

Returns

| The class associated with the given alias. If not found, an exception will be thrown.

Throws

| `ReferenceError` — The alias was not registered.

See also

registerClassAlias()

navigateToURL | () |  |

`public navigateToURL(, = null)`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Opens or replaces a window in the application that contains the Flash Player container (usually a browser).

Note: For local content running in a browser, calls to the `navigateToURL()` method that specify a `"javascript:"` pseudo-protocol (via a `URLRequest` object passed as the first parameter) are only permitted if the SWF file and the containing web page (if there is one) are in the local-trusted security sandbox. Some browsers do not support using the javascript protocol with the `navigateToURL()` method. Instead, consider using the `call()` method of the `ExternalInterface` API to invoke JavaScript methods within the enclosing HTML page.

For more information, see the following:

- The security chapter in the Programming ActionScript 3.0 book and the latest comments on LiveDocs
- The Flash Player 9 Security white paper
- The Flash Player Developer Center Topic: Security

Parameters

| `request` — A URLRequest object that specifies the URL to navigate to.
| `window` (default = `null`)`` — The browser window or HTML frame in which to display the document indicated by the `request` parameter. You can enter the name of a specific window or use one of the following values: `"_self"` specifies the current frame in the current window. `"_blank"` specifies a new window. `"_parent"` specifies the parent of the current frame. `"_top"` specifies the top-level frame in the current window. If you do not specify a value for this parameter, a new empty window is created. In the stand-alone player, you can either specify a new (`"_blank"`) window or a named window. The other values don't apply. Note: When code in a SWF file that is running in the local-with-filesystem sandbox calls the `navigateToURL()` function and specifies a custom window name for the `window` parameter, the window name is transfered into a random name. The name is in the form `"_flashXXXXXXXX"`, where each X represents a random hexadecimal digit. Within the same session (until you close the containing browser window), if you call the function again and specify the same name for the `window` parameter, the same random string is used.

Throws

| `SecurityError` — This error is thrown in the following situations: Local untrusted SWF files may not communicate with the Internet. You can avoid this situation by reclassifying this SWF file as local-with-networking or trusted. A navigate operation attempted to evaluate a scripting pseudo-URL, but the containing document (usually an HTML document in a browser) is from a sandbox to which you do not have access. You can avoid this situation by specifying `allowScriptAccess="always"` in the containing document. You cannot navigate the special windows `"_self"`, `"_top"`, or `"_parent"` if your SWF file is contained by an HTML page that has set the `allowScriptAccess` to `"none"`, or to `"sameDomain"` when the domains of the HTML file and the SWF file do not match. You cannot navigate a window with a nondefault name from within a SWF file that is in the local-with-filesystem sandbox.

See also

flash.external.ExternalInterface.call()
Flash Player security
Example
The following example opens the URL http://www.adobe.com in a new browser window and passes data about a user session, captured in a URLVariables object, to the web server.

    package {
        import flash.display.Sprite;
        import flash.net.navigateToURL;
        import flash.net.URLRequest;
        import flash.net.URLVariables;

        public class NavigateToURLExample extends Sprite {

            public function NavigateToURLExample() {
                var url:String = "http://www.adobe.com";
                var variables:URLVariables = new URLVariables();
                variables.exampleSessionId = new Date().getTime();
                variables.exampleUserLabel = "Your Name";
                var request:URLRequest = new URLRequest(url);
                request.data = variables;
                try {
                    navigateToURL(request);
                }
                catch (e:Error) {
                    // handle error here
                }
            }
        }
    }

registerClassAlias | () |  |

`public registerClassAlias(, )`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Preserves the class (type) of an object when the object is encoded in Action Message Format (AMF). When you encode an object into AMF, this function saves the alias for its class, so that you can recover the class when decoding the object. If the encoding context did not register an alias for an object's class, the object is encoded as an anonymous object. Similarly, if the decoding context does not have the same alias registered, an anonymous object is created for the decoded data.

LocalConnection, ByteArray, SharedObject, NetConnection and NetStream are all examples of classes that encode objects in AMF.

The encoding and decoding contexts do not need to use the same class for an alias; they can intentionally change classes, provided that the destination class contains all of the members that the source class serializes.

Parameters

| `aliasName` — The alias to use.
| `classObject` — The class associated with the given alias.

Throws

| `TypeError` — If either parameter is `null`.

See also

ObjectEncoding class
Example
This example uses the `registerClassAlias()` function to register an alias (`com.example.eg`) for the class ExampleClass. Because an alias is registered for the class, the object is able to be deserialized as an instance of ExampleClass, and the code outputs `true`. If the `registerClassAlias()` call were removed, the code would output `false`.

    package {
        import flash.display.Sprite;
        import flash.net.registerClassAlias;
        import flash.utils.ByteArray;

        public class RegisterClassAliasExample extends Sprite {
            public function RegisterClassAliasExample() {
                registerClassAlias("com.example.eg", ExampleClass);
                var eg1:ExampleClass = new ExampleClass();
                var ba:ByteArray = new ByteArray();
                ba.writeObject(eg1);
                ba.position = 0;
                var eg2:* = ba.readObject();
                trace(eg2 is ExampleClass); // true
            }
        }
    }

    class ExampleClass {}

sendToURL | () |  |

`public sendToURL()`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Sends a URL request to a server, but ignores any response.

To examine the server response, use the `URLLoader.load()` method instead.

For Flash Player 9 and later, you can prevent a SWF file from using this method by setting the `allowNetworking` parameter of the the `object` and `embed` tags in the HTML page that contains the SWF content.

For more information, see the following:

- The Flash Player 9 Security white paper
- The Flash Player Developer Center Topic: Security

Parameters

| `request` — A URLRequest object specifying the URL to send data to.

Throws

| `SecurityError` — Local untrusted SWF files cannot communicate with the Internet. You can avoid this situation by reclassifying this SWF file as local-with-networking or trusted.

See also

Flash Player security
Example
The following example passes data about a user session, captured in a URLVariables object, to the application at http://www.yourDomain.com/application.jsp.

     package {
        import flash.display.Sprite;
        import flash.net.URLRequest;
        import flash.net.URLVariables;
        import flash.net.sendToURL;

        public class SendToURLExample extends Sprite {

            public function SendToURLExample() {
                var url:String = "http://www.yourDomain.com/application.jsp";
                var variables:URLVariables = new URLVariables();
                variables.sessionId = new Date().getTime();
                variables.userLabel = "Your Name";

                var request:URLRequest = new URLRequest(url);
                request.data = variables;
                trace("sendToURL: " + request.url + "?" + request.data);
                try {
                    sendToURL(request);
                }
                catch (e:Error) {
                    // handle error here
                }
            }
        }
    }

Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Tue May 20 2008, 04:03 AM -07:00