ActionScript 3.0 Language and Components Reference | All Packages | All Classes | Language Elements | Index | Appendixes | Conventions | Frames No Frames |
Socket

Package | flash.net
Class | public class Socket
Inheritance | Socket EventDispatcher Object
Implements | IDataInput, IDataOutput

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The Socket class enables ActionScript code to make socket connections and to read and write raw binary data. It is similar to XMLSocket but does not dictate the format of the received or transmitted data.

The Socket class is useful for working with servers that use binary protocols.

To use the methods of the Socket class, you must first use the constructor, `new Socket`, to create a Socket object.

SWF files in the local-with-filesystem sandbox may not use sockets.

Socket policy files on the target host specify the hosts from which SWF files can make socket connections, and the ports to which those connections can be made. The security requirements with regard to socket policy files have become more stringent in the last several releases of Flash Player. In all versions of Flash Player, Adobe recommends the use of a socket policy file; in some circumstances, a socket policy file is required. Therefore, if you are using XMLSocket objects, make sure the target host provides a socket policy file if necessary.

The following list summarizes the requirements for socket policy files in different versions of Flash Player:

- In Flash Player 9.0.124.0 and later, a socket policy file is required for any Socket connection. That is, a socket policy file on the target host is required no matter what port you are connecting to, and is required even if you are connecting to a port on the same host that is serving the SWF file.
- In Flash Player versions 9.0.115.0 and earlier, if you want to connect to a port number below 1024, or if you want to connect to a host different than the one serving the SWF file, a socket policy file on the target host is required.
- In Flash Player 9.0.115.0, even if a socket policy file isn't required, a warning is displayed when using the Flash Debug Player if the target host doesn't serve a socket policy file.

For more information related to security, see the following:

- The security chapter in the Programming ActionScript 3.0 book and the latest comments on LiveDocs
- The Flash Player Developer Center Topic: Security

View the examples

See also

Socket connections

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | bytesAvailable : uint [read-only] The number of bytes of data available for reading in the input buffer. | Socket
|  | connected : Boolean [read-only] Indicates whether this Socket object is currently connected. | Socket
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | endian : String Indicates the byte order for the data; possible values are constants from the flash.utils.Endian class, Endian.BIG_ENDIAN or Endian.LITTLE_ENDIAN. | Socket
|  | objectEncoding : uint Controls the version of AMF used when writing or reading an object. | Socket
|  | prototype : Object [static] A reference to the prototype object of a class or function object. | Object

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | Socket(host:String = null, port:int = 0) Creates a Socket object. | Socket
|  | addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registers an event listener object with an EventDispatcher object so that the listener receives notification of an event. | EventDispatcher
|  | close():void Closes the socket. | Socket
|  | connect(host:String, port:int):void Connects the socket to the specified host and port. | Socket
|  | dispatchEvent(event:Event):Boolean Dispatches an event into the event flow. | EventDispatcher
|  | flush():void Flushes any accumulated data in the socket's output buffer. | Socket
|  | hasEventListener(type:String):Boolean Checks whether the EventDispatcher object has any listeners registered for a specific type of event. | EventDispatcher
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | readBoolean():Boolean Reads a Boolean value from the socket. | Socket
|  | readByte():int Reads a signed byte from the socket. | Socket
|  | readBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void Reads the number of data bytes specified by the length parameter from the socket. | Socket
|  | readDouble():Number Reads an IEEE 754 double-precision floating-point number from the socket. | Socket
|  | readFloat():Number Reads an IEEE 754 single-precision floating-point number from the socket. | Socket
|  | readInt():int Reads a signed 32-bit integer from the socket. | Socket
|  | readMultiByte(length:uint, charSet:String):String Reads a multibyte string from the byte stream, using the specified character set. | Socket
|  | readObject():* Reads an object from the socket, encoded in AMF serialized format. | Socket
|  | readShort():int Reads a signed 16-bit integer from the socket. | Socket
|  | readUnsignedByte():uint Reads an unsigned byte from the socket. | Socket
|  | readUnsignedInt():uint Reads an unsigned 32-bit integer from the socket. | Socket
|  | readUnsignedShort():uint Reads an unsigned 16-bit integer from the socket. | Socket
|  | readUTF():String Reads a UTF-8 string from the socket. | Socket
|  | readUTFBytes(length:uint):String Reads the number of UTF-8 data bytes specified by the length parameter from the socket, and returns a string. | Socket
|  | removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Removes a listener from the EventDispatcher object. | EventDispatcher
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object
|  | willTrigger(type:String):Boolean Checks whether an event listener is registered with this EventDispatcher object or any of its ancestors for the specified event type. | EventDispatcher
|  | writeBoolean(value:Boolean):void Writes a Boolean value to the socket. | Socket
|  | writeByte(value:int):void Writes a byte to the socket. | Socket
|  | writeBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void Writes a sequence of bytes from the specified byte array. | Socket
|  | writeDouble(value:Number):void Writes an IEEE 754 double-precision floating-point number to the socket. | Socket
|  | writeFloat(value:Number):void Writes an IEEE 754 single-precision floating-point number to the socket. | Socket
|  | writeInt(value:int):void Writes a 32-bit signed integer to the socket. | Socket
|  | writeMultiByte(value:String, charSet:String):void Writes a multibyte string from the byte stream, using the specified character set. | Socket
|  | writeObject(object:*):void Write an object to the socket in AMF serialized format. | Socket
|  | writeShort(value:int):void Writes a 16-bit integer to the socket. | Socket
|  | writeUnsignedInt(value:uint):void Writes a 32-bit unsigned integer to the socket. | Socket
|  | writeUTF(value:String):void Writes the following data to the socket: a 16-bit unsigned integer, which indicates the length of the specified UTF-8 string in bytes, followed by the string itself. | Socket
|  | writeUTFBytes(value:String):void Writes a UTF-8 string to the socket. | Socket

Events
Hide Inherited Events
Show Inherited Events

| Event | Summary | Defined By
--- | --- | --- | ---
|  | activate | Dispatched when Flash Player gains operating system focus and becomes active. | EventDispatcher
|  | close | Dispatched when the server closes the socket connection. | Socket
|  | connect | Dispatched when a network connection has been established. | Socket
|  | deactivate | Dispatched when Flash Player loses operating system focus and is becoming inactive. | EventDispatcher
|  | ioError | Dispatched when an input/output error occurs that causes a send or load operation to fail. | Socket
|  | securityError | Dispatched if a call to Socket.connect() attempts to connect either to a server outside the caller's security sandbox or to a port lower than 1024. | Socket
|  | socketData | Dispatched when a socket has received data. | Socket

Property Detail

bytesAvailable | property

`bytesAvailable:uint` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

The number of bytes of data available for reading in the input buffer.

Your code must access `bytesAvailable` to ensure that sufficient data is available before trying to read it with one of the `read` methods.

Implementation
`public function get bytesAvailable():uint`

connected | property |

`connected:Boolean` [read-only]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Indicates whether this Socket object is currently connected. A call to this property returns a value of `true` if the socket is currently connected, or `false` otherwise.

Implementation
`public function get connected():Boolean`

endian | property |

`endian:String` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Indicates the byte order for the data; possible values are constants from the flash.utils.Endian class, `Endian.BIG_ENDIAN` or `Endian.LITTLE_ENDIAN`.

The default value is `Endian.BIG_ENDIAN`.

Implementation
`public function get endian():String`
`public function set endian(value:String):void`

See also

flash.utils.Endian

objectEncoding | property |

`objectEncoding:uint` [read-write]

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Controls the version of AMF used when writing or reading an object.

Implementation
`public function get objectEncoding():uint`
`public function set objectEncoding(value:uint):void`

See also

ObjectEncoding class
readObject()
writeObject()
Constructor Detail

Socket | () | Constructor

`public function Socket(host:String = null, port:int = 0)`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Creates a Socket object. If no parameters are specified, an initially disconnected socket is created. If parameters are specified, a connection is attempted to the specified host and port.

Parameters

| `host:String` (default = `null`)`` — A fully qualified DNS domain name, or an IP address in the form 111.222.333.444. You can also specify `null` to connect to the host server on which the SWF file resides. If the SWF file issuing this call is running in a web browser, `host` must be in the same domain as the SWF file.
| `port:int` (default = `0`)`` — The TCP port number on the target host used to establish a connection. In Flash Player 9.0.124.0 and later, the target host must serve a socket policy file specifying that socket connections are permitted from the host serving the SWF file to the specified port. In earlier versions of Flash Player, a socket policy file is required only if you want to connect to a port number below 1024, or if you want to connect to a host different than the one serving the SWF file.

Events

| `connect:`Event`` — Dispatched when a network connection has been established.
| `ioError:`IOErrorEvent`` — Dispatched when an input/output error occurs that causes the connection to fail.
| `securityError:`SecurityErrorEvent`` — Dispatched if a call to `Socket.connect()` attempts to connect either to a server that doesn't serve a socket policy file, or to a server whose policy file doesn't grant the calling host access to the specified port. For more information about socket policy files, see the "Flash Player Security" chapter in Programming ActionScript 3.0.

Throws

| `SecurityError` — This error occurs for the following reasons: Local untrusted SWF files cannot communicate with the Internet. You can work around this problem by reclassifying this SWF file as local-with-networking or trusted. You cannot specify a socket port higher than 65535.

Method Detail

close | () | method

`public function close():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Closes the socket. You cannot read or write any data after the `close()` method has been called.

The `close` event is dispatched only when the server closes the connection; it is not dispatched when you call the `close()` method.

You can reuse the Socket object by calling the `connect()` method on it again.

Throws

| `IOError` — The socket could not be closed, or the socket was not open.

connect | () | method |

`public function connect(host:String, port:int):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Connects the socket to the specified host and port. If the connection fails immediately, either an event is dispatched or an exception is thrown: an error event is dispatched if a host was specified, and an exception is thrown if no host was specified. Otherwise, the status of the connection is reported by an event. If the socket is already connected, the existing connection is closed first.

Parameters

| `host:String` — The name or IP address of the host to connect to. If no host is specified, the host that is contacted is the host where the calling SWF file resides. If you do not specify a host, use an event listener to determine whether the connection was successful.
| `port:int` — The port number to connect to.

Events

| `connect:`Event`` — Dispatched when a network connection has been established.
| `ioError:`IOErrorEvent`` — Dispatched if a host is specified and an input/output error occurs that causes the connection to fail.
| `securityError:`SecurityErrorEvent`` — Dispatched if a call to `Socket.connect()` attempts to connect either to a server that doesn't serve a socket policy file, or to a server whose policy file doesn't grant the calling host access to the specified port. For more information, see the "Flash Player Security" chapter in Programming ActionScript 3.0.

Throws

| `IOError` — No host was specified and the connection failed.
| `SecurityError` — This error occurs for the following reasons: Local untrusted SWF files may not communicate with the Internet. You can work around this by reclassifying this SWF file as local-with-networking or trusted. You cannot specify a socket port higher than 65535. In the HTML page that contains the SWF content, the `allowNetworking` parameter of the the `object` and `embed` tags is set to `"none"`.

See also

Flash Player security

flush | () | method |

`public function flush():void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Flushes any accumulated data in the socket's output buffer. Data written by the `write` methods is not immediately transmitted; it is queued until the `flush()` method is called.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readBoolean | () | method |

`public function readBoolean():Boolean`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads a Boolean value from the socket. After reading a single byte, the method returns `true` if the byte is nonzero, and `false` otherwise.

Returns

| `Boolean` — A value of `true` if the byte read is nonzero, otherwise `false`.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readByte | () | method |

`public function readByte():int`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads a signed byte from the socket.

Returns

| `int` — A value from -128 to 127.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readBytes | () | method |

`public function readBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads the number of data bytes specified by the `length` parameter from the socket. The bytes are read into the specified byte array, starting at the position indicated by `offset`.

Parameters

| `bytes:ByteArray` — The ByteArray object to read data into.
| `offset:uint` (default = `0`)`` — The offset at which data reading should begin in the byte array.
| `length:uint` (default = `0`)`` — The number of bytes to read. The default value of 0 causes all available data to be read.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readDouble | () | method |

`public function readDouble():Number`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads an IEEE 754 double-precision floating-point number from the socket.

Returns

| `Number` — An IEEE 754 double-precision floating-point number.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readFloat | () | method |

`public function readFloat():Number`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads an IEEE 754 single-precision floating-point number from the socket.

Returns

| `Number` — An IEEE 754 single-precision floating-point number.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readInt | () | method |

`public function readInt():int`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads a signed 32-bit integer from the socket.

Returns

| `int` — A value from -2147483648 to 2147483647.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readMultiByte | () | method |

`public function readMultiByte(length:uint, charSet:String):String`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads a multibyte string from the byte stream, using the specified character set.

Parameters

| `length:uint` — The number of bytes from the byte stream to read.
| `charSet:String` — The string denoting the character set to use to interpret the bytes. Possible character set strings include `"shift_jis"`, `"CN-GB"`, and `"iso-8859-1"`. For a complete list, see Supported Character Sets. Note: If the value for the `charSet` parameter is not recognized by the current system, then Flash Player uses the system's default code page as the character set. For example, a value for the `charSet` parameter, as in `myTest.readMultiByte(22, "iso-8859-01")` that uses `01` instead of `1` might work on your development machine, but not on another machine. On the other machine, Flash Player will use the system's default code page.

Returns

| `String` — A UTF-8 encoded string.

Throws

| `EOFError` — There is insufficient data available to read.

readObject | () | method |

`public function readObject():*`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads an object from the socket, encoded in AMF serialized format.

Returns

| `*` — The deserialized object

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

ObjectEncoding

readShort | () | method |

`public function readShort():int`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads a signed 16-bit integer from the socket.

Returns

| `int` — A value from -32768 to 32767.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readUnsignedByte | () | method |

`public function readUnsignedByte():uint`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads an unsigned byte from the socket.

Returns

| `uint` — A value from 0 to 255.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readUnsignedInt | () | method |

`public function readUnsignedInt():uint`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads an unsigned 32-bit integer from the socket.

Returns

| `uint` — A value from 0 to 4294967295.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readUnsignedShort | () | method |

`public function readUnsignedShort():uint`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads an unsigned 16-bit integer from the socket.

Returns

| `uint` — A value from 0 to 65535.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readUTF | () | method |

`public function readUTF():String`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads a UTF-8 string from the socket. The string is assumed to be prefixed with an unsigned short integer that indicates the length in bytes.

Returns

| `String` — A UTF-8 string.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

readUTFBytes | () | method |

`public function readUTFBytes(length:uint):String`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Reads the number of UTF-8 data bytes specified by the `length` parameter from the socket, and returns a string.

Parameters

| `length:uint` — The number of bytes to read.

Returns

| `String` — A UTF-8 string.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

writeBoolean | () | method |

`public function writeBoolean(value:Boolean):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a Boolean value to the socket. This method writes a single byte, with either a value of 1 (`true`) or 0 (`false`).

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:Boolean` — The value to write to the socket: 1 (`true`) or 0 (`false`).

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeByte | () | method |

`public function writeByte(value:int):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a byte to the socket.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:int` — The value to write to the socket. The low 8 bits of the value are used; the high 24 bits are ignored.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeBytes | () | method |

`public function writeBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a sequence of bytes from the specified byte array. The write operation starts at the position specified by `offset`.

If you omit the `length` parameter the default length of 0 causes the method to write the entire buffer starting at `offset`.

If you also omit the `offset` parameter, the entire buffer is written.

If `offset` or `length` is out of range, they are adjusted to match the beginning and end of the `bytes` array.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `bytes:ByteArray` — The ByteArray object to write data from.
| `offset:uint` (default = `0`)`` — The zero-based offset into the `bytes` ByteArray object at which data writing should begin.
| `length:uint` (default = `0`)`` — The number of bytes to write. The default value of 0 causes the entire buffer to be written, starting at the value specified by the `offset` parameter.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeDouble | () | method |

`public function writeDouble(value:Number):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes an IEEE 754 double-precision floating-point number to the socket.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:Number` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeFloat | () | method |

`public function writeFloat(value:Number):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes an IEEE 754 single-precision floating-point number to the socket.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:Number` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeInt | () | method |

`public function writeInt(value:int):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a 32-bit signed integer to the socket.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:int` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeMultiByte | () | method |

`public function writeMultiByte(value:String, charSet:String):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a multibyte string from the byte stream, using the specified character set.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:String` — The string value to be written.
| `charSet:String` — The string denoting the character set to use to interpret the bytes. Possible character set strings include `"shift_jis"`, `"CN-GB"`, and `"iso-8859-1"`. For a complete list, see Supported Character Sets.

See also

flush()

writeObject | () | method |

`public function writeObject(object:*):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Write an object to the socket in AMF serialized format.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `object:*` — The object to be serialized.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()
ObjectEncoding

writeShort | () | method |

`public function writeShort(value:int):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a 16-bit integer to the socket. The bytes written are as follows:

    (v >> 8) & 0xff v & 0xff

The low 16 bits of the parameter are used; the high 16 bits are ignored.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:int` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeUnsignedInt | () | method |

`public function writeUnsignedInt(value:uint):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a 32-bit unsigned integer to the socket.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:uint` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeUTF | () | method |

`public function writeUTF(value:String):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes the following data to the socket: a 16-bit unsigned integer, which indicates the length of the specified UTF-8 string in bytes, followed by the string itself.

Before writing the string, the method calculates the number of bytes needed to represent all characters of the string.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:String` — The string to write to the socket.

Throws

| `RangeError` — The length is larger than 65535.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()

writeUTFBytes | () | method |

`public function writeUTFBytes(value:String):void`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Writes a UTF-8 string to the socket.

Note: Data written by this method is not immediately transmitted; it is queued until the `flush()` method is called.

Parameters

| `value:String` — The string to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

See also

flush()
Event Detail

close | Event

Event Object Type: `flash.events.Event`
Event.type property = `flash.events.Event.CLOSE`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Dispatched when the server closes the socket connection. The `close` event is dispatched only when the server closes the connection; it is not dispatched when you call the `Socket.close()` method.

Defines the value of the `type` property of a `close` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object whose connection has been closed.

connect | Event |

Event Object Type: `flash.events.Event`
Event.type property = `flash.events.Event.CONNECT`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Dispatched when a network connection has been established.

Defines the value of the `type` property of a `connect` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Socket or XMLSocket object that has established a network connection.

ioError | Event |

Event Object Type: `flash.events.IOErrorEvent`
IOErrorEvent.type property = `flash.events.IOErrorEvent.IO_ERROR`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Dispatched when an input/output error occurs that causes a send or load operation to fail.

Defines the value of the `type` property of an `ioError` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The network object experiencing the input/output error.
`text` | Text to be displayed as an error message.

securityError | Event |

Event Object Type: `flash.events.SecurityErrorEvent`
SecurityErrorEvent.type property = `flash.events.SecurityErrorEvent.SECURITY_ERROR`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Dispatched if a call to `Socket.connect()` attempts to connect either to a server outside the caller's security sandbox or to a port lower than 1024.

The `SecurityErrorEvent.SECURITY_ERROR` constant defines the value of the `type` property of a `securityError` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The network object reporting the security error.
`text` | Text to be displayed as an error message.

See also

Socket.connect()
Flash Player security

socketData | Event |

Event Object Type: `flash.events.ProgressEvent`
ProgressEvent.type property = `flash.events.ProgressEvent.SOCKET_DATA`

Language Version : | ActionScript 3.0

Player Version : | Flash Player 9

Dispatched when a socket has received data. Events of type `socketData` do not use the `ProgressEvent.bytesTotal` property.

Defines the value of the `type` property of a `socketData` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event.
`bytesLoaded` | The number of items or bytes loaded at the time the listener processes the event.
`bytesTotal` | 0; this property is not used by `socketData` event objects.
`target` | The Socket object reporting progress.

Examples How to use examples
SocketExample.as
The following example reads from and writes to a socket and outputs information transmitted during socket events. Highlights of the example follow:

1. The constructor creates a `CustomSocket` instance named `socket` and passes the host name `localhost` and port 80 as arguments. Since `CustomSocket` extends Socket, a call to `super()` calls Socket's constructor with `localhost` as the host name and 80 as the port number.
2. The example then calls the `configureListeners()` method, which adds listeners for Socket events.

Note: To run the example, you need a server running on the same domain where the SWF resides (in the example, `localhost`) and listening on port 80.

    package {
        import flash.display.Sprite;

        public class SocketExample extends Sprite {

            public function SocketExample() {
                var socket:CustomSocket = new CustomSocket("localhost", 80);
            }
        }
    }

    import flash.errors.*;
    import flash.events.*;
    import flash.net.Socket;

    class CustomSocket extends Socket {
        private var response:String;

        public function CustomSocket(host:String = null, port:uint = 0) {
            super(host, port);
            configureListeners();
        }

        private function configureListeners():void {
            addEventListener(Event.CLOSE, closeHandler);
            addEventListener(Event.CONNECT, connectHandler);
            addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);
        }

        private function writeln(str:String):void {
            str += "\n";
            try {
                writeUTFBytes(str);
            }
            catch(e:IOError) {
                trace(e);
            }
        }

        private function sendRequest():void {
            trace("sendRequest");
            response = "";
            writeln("GET /");
            flush();
        }

        private function readResponse():void {
            var str:String = readUTFBytes(bytesAvailable);
            response += str;
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
            trace(response.toString());
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
            sendRequest();
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function socketDataHandler(event:ProgressEvent):void {
            trace("socketDataHandler: " + event);
            readResponse();
        }
    }

Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Tue May 20 2008, 04:02 AM -07:00